RoboMind Documentation
Documentation
Programming structures
Overview
Introduction
Basisinstructies
Programming structures
- comment
- loops
- if-structures
- procedures
- end
Example scripts

Programming structures

Here you'll find the grammatical structures that are allowed to define the behavior of the robot.

Comments

# free text that will not be evaluated

All text that appears after a hash, '#', will not be interpreted as instructions. The robot will proceed to read the next line in the script. Use this possibility to annotate parts of the script, just for yourself, as documentation about how these parts work

Loops

повторение(n){...instructions...}
repeats the instructions between curly brackets exactly n times.

Example:

# a square of 2x2
повторение(4)
{
	напред(2)
	надясно
}
                  

повторение{...instructions...}
just keeps repeating the instructions between curly brackets for ever.

Example:

# just goes forward
# (but eventually will stay hitting a wall)
повторение
{
	напред(1)
}

докато(condition){...instructions...}
repeats the instructions between curly brackets as long as the condition holds. This condition must be a perception/seeing instruction (for example напредСвободно)

Example:

# keeps going forward, 
# but stops when it can't go any further
докато(напредСвободно)
{
	напред(1)
}

скъсване
allows you to jump out of the loop (e.g. a repeat section) so it stops performing the instructions between curly brackets. The robot will resume performing the instructions left after the closing curly bracket of the loop.

Example:

# keep going forward, until you can't go any further
повторение
{
	ако(напредПрепяствие)	{
		скъсване
	}
	иначе
	{	
		напред(1)
	}
}
                  

If-structures

ако(condition){...instructions...}
will perform the the instructions between curly brackets, only if the condition holds. Else the robot immediately steps to the instructions written after the closing curly bracket. The condition must be a perception/seeing instruction (for example: напредСвободно)

Example:

# if you see white paint on your left, make it black
ако(влявоБяло)
{
	наляво
	напред(1)
	оцветиЧерно
	сприОцветяване
	назад(1)
	надясно
}
                  

ако(condition){...instructions...}иначе{...instructions...}
will perform the the instructions between the first pair of curly brackets, only if the condition holds. Then it will not perform the instructions of the else block (second pair of instructions). When the condition does not hold, the robot will only perform the instructions in between the second pair of curly brackets. After it performed one of the instruction blocks, it will read the instructions after the last curly bracket. The condition must be a perception/seeing instruction (for example: напредСвободно)

Example:

# if you see white paint on your left, make it black
# else drive a few steps forward
ако(влявоБяло)
{
	наляво
	напред(1)
	оцветиЧерно
	сприОцветяване
	назад(1)
	надясно
}
иначе
{
	напред(3)
}
                  

Logical
expressions

The conditions of if- and repeatWhile-structures is a so-called logical expression. Such an expression will result in the value вярно or грешно, which is then used to decide to step to the appropriate part of the code to resume execution.

A logical expression can be a perception instruction, e.g.: вярно. Basic instructions may also be composed with the boolean operators ~, &, |.

Example:

ако(влявоБяло)
{
    наляво
    напред(1)    
}

The condition can however also be refined to more indicate more precisely when the corresponding instructions should be executed by using (a combination of) the following operators.

Operation
Alternative
notation
Number of
arguments
Explanation
не ~ 1

Negates the value of the argument :

Truth table :
~ вярно = грешно
~ грешно = вярно

Example:
~ напредСвободно

и & 2

Only true when both arguments are true.

Truth table:
вярно & вярно = вярно
вярно & грешно = грешно
грешно & вярно = грешно
грешно & грешно = грешно

Example:
напредСвободно & вдясноБяло

или | 2

True when at least one of the arguments is true.

Truth table:
вярно | вярно = вярно
вярно | грешно = вярно
грешно | вярно = вярно
грешно | грешно = грешно

Example:
напредСвободно | вдясноБяло

The values вярно and грешно can also be applied directly as if it was a perception instruction.

The order of the operators is of importance (just like multiplying and adding numbers). The operation ~ binds strongest, followed by &, followed by |. Brackets can be used to influence the order of evaluation.

Examples:

				
докато(не напредСвободно и (влявоБяло или вдясноБяло)){
    напред(1)
}

ако(шансМонета и не вдясноБяло)
{
    надясно
    назад(1)
}

ако(вярно и грешно){
    # this instruction is never executed
    напред(1)
}
              

Procedures

процедура name(par1, par2, ... , parN){...instructions...}
defines a new procedure with the name you want. The procedure can have zero or more parameters, which you may also give useful names. Here they are called par1, par2, . . . , parN. These are the variables you can use in the instruction between curly brackets. The code in a procedure will not be performed automatically, you have to write a 'procedure call' every time you want to perform the instructions in the definition (See next instruction).
Tip: create a new procedure when when you you use a sequence of instructions more than once.

Example:

# define how to draw a rectangle
процедура rectangle(width, height)
{
	оцветиБяло
	повторение(2)
	{
		напред(height)
		надясно
		напред(width)
		надясно
	}
	сприОцветяване
}
                  

name(arg1, arg2, . . . , argN)
is the call to the procedure with the corresponding name and the same amount parameters as you have arguments. The argument, here called arg1, arg2, . . . , argN, are the particular values that will be used in the procedure definition.

Example:

# these instructions will be performed
напред(1)
rectangle(3,2) # a call to the 'rectangle' procedure
напред(3)
rectangle(1,4) # another call with other arguments


# this is the definition of 'rectangle'
процедура rectangle(width, height)
{
	оцветиБяло
	повторение(2)
	{
		напред(height)
		надясно
		напред(width)
		надясно
	}
	сприОцветяване
}                  

End

край
will cause the entire program to stop when this instruction is performed.

Example:

# stop after 5 steps, or earlier when you encounter a beacon on the right
повторение(5)
{
	напред(1)
	ако(вдясноФар)
	{
		край # stops execution of the program
	}
}
# normal end of the program
                  
RoboMind - Copyright © 2005 - 2016 - Research Kitchen