RoboMind Documentation
Documentation
Programming structures
Overview
Introduction
Basisinstructies
Programming structures
- comment
- loops
- if-structures
- procedures
- end
Example scripts

Programming structures

Here you'll find the grammatical structures that are allowed to define the behavior of the robot.

Comments

# free text that will not be evaluated

All text that appears after a hash, '#', will not be interpreted as instructions. The robot will proceed to read the next line in the script. Use this possibility to annotate parts of the script, just for yourself, as documentation about how these parts work

Loops

חזור_על(n){...instructions...}
repeats the instructions between curly brackets exactly n times.

Example:

# a square of 2x2
חזור_על(4)
{
	לך_קדימה(2)
	פנה_ימינה
}
                  

חזור_על{...instructions...}
just keeps repeating the instructions between curly brackets for ever.

Example:

# just goes forward
# (but eventually will stay hitting a wall)
חזור_על
{
	לך_קדימה(1)
}

חזור_אם(condition){...instructions...}
repeats the instructions between curly brackets as long as the condition holds. This condition must be a perception/seeing instruction (for example קדימה_פנוי)

Example:

# keeps going forward, 
# but stops when it can't go any further
חזור_אם(קדימה_פנוי)
{
	לך_קדימה(1)
}

הפסק
allows you to jump out of the loop (e.g. a repeat section) so it stops performing the instructions between curly brackets. The robot will resume performing the instructions left after the closing curly bracket of the loop.

Example:

# keep going forward, until you can't go any further
חזור_על
{
	אם(קדימה_מחסום)	{
		הפסק
	}
	אחרת
	{	
		לך_קדימה(1)
	}
}
                  

If-structures

אם(condition){...instructions...}
will perform the the instructions between curly brackets, only if the condition holds. Else the robot immediately steps to the instructions written after the closing curly bracket. The condition must be a perception/seeing instruction (for example: קדימה_פנוי)

Example:

# if you see white paint on your left, make it black
אם(שמאלה_לבן)
{
	פנה_שמאלה
	לך_קדימה(1)
	הכן_צבע_שחור
	הסתר_צבעים
	לך_אחורה(1)
	פנה_ימינה
}
                  

אם(condition){...instructions...}אחרת{...instructions...}
will perform the the instructions between the first pair of curly brackets, only if the condition holds. Then it will not perform the instructions of the else block (second pair of instructions). When the condition does not hold, the robot will only perform the instructions in between the second pair of curly brackets. After it performed one of the instruction blocks, it will read the instructions after the last curly bracket. The condition must be a perception/seeing instruction (for example: קדימה_פנוי)

Example:

# if you see white paint on your left, make it black
# else drive a few steps forward
אם(שמאלה_לבן)
{
	פנה_שמאלה
	לך_קדימה(1)
	הכן_צבע_שחור
	הסתר_צבעים
	לך_אחורה(1)
	פנה_ימינה
}
אחרת
{
	לך_קדימה(3)
}
                  

Logical
expressions

The conditions of if- and repeatWhile-structures is a so-called logical expression. Such an expression will result in the value אמת or שקר, which is then used to decide to step to the appropriate part of the code to resume execution.

A logical expression can be a perception instruction, e.g.: אמת. Basic instructions may also be composed with the boolean operators ~, &, |.

Example:

אם(שמאלה_לבן)
{
    פנה_שמאלה
    לך_קדימה(1)    
}

The condition can however also be refined to more indicate more precisely when the corresponding instructions should be executed by using (a combination of) the following operators.

Operation
Alternative
notation
Number of
arguments
Explanation
לא ~ 1

Negates the value of the argument :

Truth table :
~ אמת = שקר
~ שקר = אמת

Example:
~ קדימה_פנוי

ו_ & 2

Only true when both arguments are true.

Truth table:
אמת & אמת = אמת
אמת & שקר = שקר
שקר & אמת = שקר
שקר & שקר = שקר

Example:
קדימה_פנוי & ימינה_לבן

או | 2

True when at least one of the arguments is true.

Truth table:
אמת | אמת = אמת
אמת | שקר = אמת
שקר | אמת = אמת
שקר | שקר = שקר

Example:
קדימה_פנוי | ימינה_לבן

The values אמת and שקר can also be applied directly as if it was a perception instruction.

The order of the operators is of importance (just like multiplying and adding numbers). The operation ~ binds strongest, followed by &, followed by |. Brackets can be used to influence the order of evaluation.

Examples:

				
חזור_אם(לא קדימה_פנוי ו_ (שמאלה_לבן או ימינה_לבן)){
    לך_קדימה(1)
}

אם(אקראי ו_ לא ימינה_לבן)
{
    פנה_ימינה
    לך_אחורה(1)
}

אם(אמת ו_ שקר){
    # this instruction is never executed
    לך_קדימה(1)
}
              

Procedures

רוטינה name(par1, par2, ... , parN){...instructions...}
defines a new procedure with the name you want. The procedure can have zero or more parameters, which you may also give useful names. Here they are called par1, par2, . . . , parN. These are the variables you can use in the instruction between curly brackets. The code in a procedure will not be performed automatically, you have to write a 'procedure call' every time you want to perform the instructions in the definition (See next instruction).
Tip: create a new procedure when when you you use a sequence of instructions more than once.

Example:

# define how to draw a rectangle
רוטינה rectangle(width, height)
{
	הכן_צבע_לבן
	חזור_על(2)
	{
		לך_קדימה(height)
		פנה_ימינה
		לך_קדימה(width)
		פנה_ימינה
	}
	הסתר_צבעים
}
                  

name(arg1, arg2, . . . , argN)
is the call to the procedure with the corresponding name and the same amount parameters as you have arguments. The argument, here called arg1, arg2, . . . , argN, are the particular values that will be used in the procedure definition.

Example:

# these instructions will be performed
לך_קדימה(1)
rectangle(3,2) # a call to the 'rectangle' procedure
לך_קדימה(3)
rectangle(1,4) # another call with other arguments


# this is the definition of 'rectangle'
רוטינה rectangle(width, height)
{
	הכן_צבע_לבן
	חזור_על(2)
	{
		לך_קדימה(height)
		פנה_ימינה
		לך_קדימה(width)
		פנה_ימינה
	}
	הסתר_צבעים
}                  

End

סוף
will cause the entire program to stop when this instruction is performed.

Example:

# stop after 5 steps, or earlier when you encounter a beacon on the right
חזור_על(5)
{
	לך_קדימה(1)
	אם(ימינה_חפץ)
	{
		סוף # stops execution of the program
	}
}
# normal end of the program
                  
RoboMind - Copyright © 2005 - 2016 - Research Kitchen